	Index	Manual	Download	Source	Macros	Embedded word Case ins.
	Sitemap	Links	Forum	Tests	Projects	Embedded word Case ins.

pgmopt.htm
Class
PGMOPT
Enumerations
%PgmoptList
Encoding
PgmoptEnc
Procedures
PgmoptAssemble
PgmoptSetDefaults
PgmoptSetLinkProp

PGMOPT object contains program options which can be set in [PROGRAM] section of euroasm.ini file or in PROGRAM keyword operands.

The object is member of structures EA, SRC and PGM.

Object who wants to know a particular option should read it from PGM.Pgmopt of the latest PROGRAM on context stack.

Manipulation with PGMOPT object
Action	Source	Destination
EaCreate	Factory defaults	Ea.Pgmopt
EaCreate	Global euroasm.ini	Ea.Pgmopt
SrcCreate	Ea.Pgmopt	Src.Pgmopt
SrcCreate	Local euroasm.ini	Src.Pgmopt
PgmCreateProgram	Src.Pgmopt	Pgm.Pgmopt
PROGRAM option=	PROGRAM option=	Pgm.Pgmopt

In order to introduce a new PROGRAM option, it must be inserted into

%PgmoptList enumeration,

PGMOPT structure,

factory-default euroasm.ini file,

PgmoptAssemble configurating handler,

PgmoptSetDefaults dispatching,

VarExpand retrieving handler,

Pseudoinstructions/PROGRAM manual,

Elements/PROGRAM System %variables manual.

pgmopt PROGRAM FORMAT=COFF,MODEL=FLAT,WIDTH=32
 INCLUDEHEAD "euroasm.htm" ; Interface (structures, symbols and macros) of other modules.

 pgmopt HEAD ; Start of module interface.

↑ PGMOPT: This structure keeps assembled options from configuration file euroasm.ini or from pseudoinstruction PseudoPROGRAM.

PGMOPT STRUC                ; +00h.
.OutFilePtr             D D ; Target output file name. Quotes removed.
.OutFileSize            D D
.IconFilePtr            D D ; Embedded icon file name. Quotes removed.
.IconFileSize           D D
                            ; +10h.
.StubFilePtr            D D ; Embedded MZ stub file name. Quotes removed.
.StubFileSize           D D
.EntryPtr               D D ; Identifier or expression which specifies unevaluated entry point.
.EntrySize              D D ; It will be evaluated by PgmEvalEntry.
                            ; +20h.
.Status                 D D ; Boolean options, see below.
                        D D ; Not used.
.MaxExpansions          D D ; Maximal allowed number of expansions (%FOR,%WHILE, %REPEAT).
.MaxPasses              D D ; Maximal allowed number of assembly passes.
                            ; +30h.
.ImageBaseLow           D D ; Virtual address where the linked image should be loaded.
.ImageBaseHigh          D D
.FileAlign              D D ; Alignment of COFF sections within the output file.
.SectionAlign           D D ; Alignment of COFF sections when loaded to memory.
                            ; +40h.
.MajorOsVersion         D D
.MinorOsVersion         D D
.MajorSubsystemVersion  D D
.MinorSubsystemVersion  D D
                            ; +50h.
.MajorImageVersion      D D
.MinorImageVersion      D D
.MajorLinkerVersion     D D
.MinorLinkerVersion     D D
                            ; +60h.
.Win32VersionValue      D D
.Subsystem              D D
.DllCharacteristics     D D
                        D D ; Not used.
                            ; +70h.
.SizeOfHeapCommitLow    D D
.SizeOfHeapCommitHigh   D D
.SizeOfHeapReserveLow   D D
.SizeOfHeapReserveHigh  D D
                            ; +80h.
.SizeOfStackCommitLow   D D
.SizeOfStackCommitHigh  D D
.SizeOfStackReserveLow  D D
.SizeOfStackReserveHigh D D
  ENDSTRUC PGMOPT

↑ PgmoptEncoding: specifies boolean options kept in PGMOPT.Status
See also: %PfList

pgmoptFormatMask   = 0x0000_00FF ; FORMAT= property of program (1..255), defined in %PfPgmoptList.
pgmoptLinkPropMask = 0x0000_FF00 ; Properties concerning relation to other programs..
pgmoptLinkable     = 0x0000_0100 ; Object modules can be linked from this format.
pgmoptExportable   = 0x0000_0200 ; This output format can export its symbols (DLL).
pgmoptImportable   = 0x0000_0400 ; IMPORT declaration can be linked from this format.
pgmoptImports      = 0x0000_0800 ; Format supports dynamic linking (all but BIN,COM,MZ).
pgmoptLibrary      = 0x0000_1000 ; This format is a library (LIBCOF,LIBOMF).
pgmoptExecutable   = 0x0000_2000 ; This format can be executed (COM,MZ,PE).
pgmoptImage        = 0x0000_4000 ; This format is a linked image (BIN,COM,MZ,PE,DLL).
pgmoptLibMember    = 0x0000_8000 ; This module (OMF|COFF) was loaded from a library (LIBOMF|LIBCOF).
pgmoptModelMask    = 0x007F_0000 ; MODEL=  property of program.
pgmoptTINY         = 0x0001_0000
pgmoptSMALL        = 0x0002_0000
pgmoptMEDIUM       = 0x0004_0000
pgmoptCOMPACT      = 0x0008_0000
pgmoptLARGE        = 0x0010_0000
pgmoptHUGE         = 0x0020_0000
pgmoptFLAT         = 0x0040_0000
;                  = 0x0080_0000
pgmoptWidthMask    = 0x0700_0000 ; WIDTH= property of program.
pgmoptWidth16      = 0x0100_0000 ; pgmoptWidthMask must match sssWidthMask.
pgmoptWidth32      = 0x0200_0000
pgmoptWidth64      = 0x0400_0000
;                  = 0x0800_0000
pgmoptLISTMAP      = 0x1000_0000 ; Program options which control the listing.
pgmoptLISTGLOBALS  = 0x2000_0000
pgmoptLISTLITERALS = 0x4000_0000
;                  = 0x8000_0000

↑ %PgmoptList: enumerates names of keywords used in [PROGRAM] section of configuration file euroasm.ini and in pseudoinstruction PROGRAM.

%PgmoptList %SET DLLCHARACTERISTICS, ENTRY, FILEALIGN, FORMAT, ICONFILE, IMAGEBASE,\
   LISTMAP, LISTGLOBALS, LISTLITERALS, MODEL, MAXEXPANSIONS, MAXPASSES,            \
   MAJOROSVERSION, MAJORSUBSYSTEMVERSION, MAJORIMAGEVERSION, MAJORLINKERVERSION,   \
   MINOROSVERSION, MINORSUBSYSTEMVERSION, MINORIMAGEVERSION, MINORLINKERVERSION,   \
   WIN32VERSIONVALUE, OUTFILE, SECTIONALIGN, SIZEOFHEAPCOMMIT, SIZEOFHEAPRESERVE,  \
   SIZEOFSTACKCOMMIT, SIZEOFSTACKRESERVE, STUBFILE, SUBSYSTEM, WIDTH
%PgmoptListLength %SETL %PgmoptList

   ENDHEAD pgmopt ; End of module interface.

↑ PgmoptSetLinkProp PgmoptFormat: PgmoptSetLinkProp specifies linkage properties of all program formats recognized by EuroAssembler. Other bits are ignored.
Input: PgmoptFormat is 32bit value which specifies in its lower 8 bits program format in the encoding defined in PfPgmoptList.
Output: EAX contains program properties specified by pgmoptFormatMask and pgmoptLinkPropMask.
Error: -
Example: Invoke PgmoptSetLinkProp pgmoptCOFF ; returns EAX=pgmoptCOFF+pgmoptLinkable+pgmoptLinks
Invoked by: PfLoad PfcoffLoadModule PfomfLoadModule PgmoptAssemble

PgmoptSetLinkProp Procedure PgmoptFormat
      MOV EAX,[%PgmoptFormat]
      AND EAX,pgmoptFormatMask
      Dispatch AL,%PfPgmoptList
      JMP .90:
.pgmoptDLL:
      OR EAX,pgmoptImage|pgmoptExportable|pgmoptImportable|pgmoptImports
      JMP .90:
.pgmoptLIBCOF:
.pgmoptLIBOMF:
      OR EAX,pgmoptLibrary|pgmoptLinkable|pgmoptImportable|pgmoptImports
      JMP .90:
.pgmoptOMF:
.pgmoptCOFF:
      OR EAX,pgmoptLinkable|pgmoptImportable|pgmoptImports
      JMP .90:
.pgmoptPE:
      SetSt EAX,pgmoptImage|pgmoptExecutable|pgmoptImports
.pgmoptMZ:
.pgmoptCOM:
      SetSt EAX,pgmoptImage|pgmoptExecutable
      JMP .90:
.pgmoptBIN:
      SetSt EAX,pgmoptImage
      JMP .90:
.pgmoptRSRC:
      SetSt EAX,pgmoptLinkable
    ;  JMP .90:
 .90: MOV [%ReturnEAX],EAX
   EndProcedure PgmoptSetLinkProp

↑ PgmoptAssemble PgmoptPtr, PgmoptId, TxtPtr, TxtSize: PgmoptAssemble will evaluate one PROGRAM option and store its value to PGMOPT object.
Input: PgmoptPtr Pointer to PGMOPT structure, where the assembled option will be written to.
PgmoptId System %^variable type encoding varTypeSysPgmopt as specified in %Variable types encoding + varTypeSysEnum (ordinal number of the option in %PgmoptList). This identifies which program option is being assembled here.
TxtPtr Pointer to the option value, such as expression or enumerated token CON, Flat etc.
TxtSize Size of the option value. Spaces are stripped off.
Output: The object at PgmoptPtr is modified.
Error: Errors are reported with macro Msg.
See also: EaoptAssemble.
Invokes: DictLookup ExpEval PgmoptSetLinkProp
Invoked by: EaIniAssemble PgmParameters

PgmoptAssemble Procedure PgmoptPtr, PgmoptId, TxtPtr, TxtSize
PgmoptNamePtr  LocalVar ; Ptr to Msg !1S with option name.
PgmoptValuePtr LocalVar ; Ptr to Msg !2S with option value.
PgmoptExp LocalVar Size=SIZE#EXP ; Expression object to evaluate.
     ; Initialize error Msg parameters. 
     LEA EAX,[%TxtPtr]
     MOV EDI,[%PgmoptId]
     MOV [%PgmoptValuePtr],EAX
     AND EDI,varTypeSysEnum
     SHR EDI,16 ; EDX is now 1..%PgmoptListLength, i.e. ordinal number of enumeration.
     MOV ESI,[%TxtPtr]
     LEA EAX,[EDI+2*EDI] ; 3,6,9,12,,,
     MOV ECX,[%TxtSize]
     StripSpaces ESI,ECX
     StripQuotes ESI,ECX
     StripSpaces ESI,ECX
     LEA EAX,[DictPgmopt::+4*EAX-12] ; Ptr+Size of Pgmopt name.
     MOV [%PgmoptNamePtr],EAX ; Ptr to DD pair with option name (for the case when error occurs).
     MOV EBX,[%PgmoptPtr]
     XOR EDX,EDX
     DEC EDX
     MOV EAX,EDX ; Preinitialize EDX:EAX to -1 (default numeric value when unspecified).
     CALL [.PgmoptHandlerTable-4 + 4*EDI] ; Call the actual handler subprocedure.
     Msg cc=C,'3716',[%PgmoptNamePtr],[%PgmoptValuePtr] ; Invalid [PROGRAM] option "!1S=!2S". Ignored.
     JMP .99:
[.data]
     ALIGN DWORD
.PgmoptHandlerTable: ; Table of pointers to option handlers.
Option %FOR %PgmoptList
         DD .%Option:
       %ENDFOR Option
[.text]
; Program options callable handlers.
; Input:  CF=0
;         EDI=option ordinal number, 1..%PgmoptListLength
;         EDX:EAX=-1
;         EBX=^PGMOPT target structure where the evaluated option value will be stored.
;         ESI,ECX=pointer and size of option value in unassembled format, spaces stripped off.
; Output: CF=0, PGMOUT structure modified, EAX,ECX,EDX,EDI undefined.
; Error:  CF=1, Msg reported, EAX,ECX,EDX,EDI undefined.

; Options FORMAT, MODEL, WIDTH, FILEALIGN, SECTIONALIGN, IMAGEBASE, OUTFILE, STUBFILE, ICONFILE, TIMESTAMP
;   have variable default value (no factory defaults).

.FORMAT:XOR EAX,EAX
      JECXZ .F8: ; If FORMAT= set to empty, it will be set later to default BIN.
      Invoke DictLookup::, DictProgramFormats::, ESI,ECX
      LEA EDX,[%TxtPtr]
      Msg cc=C,'6528',[%PgmoptValuePtr],=B"%PfList" ; Illegal program format "!1S". Expected !2$.
 .F8: RstSt [EBX+PGMOPT.Status],pgmoptFormatMask+pgmoptLinkPropMask
      Invoke PgmoptSetLinkProp,EAX
      SetSt [EBX+PGMOPT.Status],EAX
      RET

.MODEL:XOR EAX,EAX
      JECXZ .M8: ; If MODEL= left empty, it will be set later according to FORMAT= option.
      Invoke DictLookup::, DictProgramModels::, ESI,ECX ; Return one of pgmoptModelMask flag.
      Msg cc=C,'3733',[%PgmoptValuePtr],DictProgramModels:: ; Illegal memory model "!1S". Expected !2L.
 .M8: RstSt [EBX+PGMOPT.Status],pgmoptModelMask
      SetSt [EBX+PGMOPT.Status],EAX
      RET

.WIDTH:
      JECXZ .W8:  ; If WIDTH= set to empty, use -1. It will be set later according to FORMAT= option.
      CALL .Integer
      JC .W9:
      MOV ECX,pgmoptWidth64
      CMP EAX,64
      JE .W8:
      MOV ECX,pgmoptWidth32
      CMP EAX,32
      JE .W8:
      MOV ECX,pgmoptWidth16
      CMP EAX,16
      JE .W8:
      Msg '3736',EAX ; Illegal program width "!1D", must be 16,32,64. Ignored.
      JMP .W9:
.W8:  RstSt [EBX+PGMOPT.Status],pgmoptWidthMask
      SetSt [EBX+PGMOPT.Status],ECX
.W9:  RET

.IMAGEBASE:
      JECXZ .IB8: ; If IMAGEBASE= left empty, use -1. It will be set later according to FORMAT= option.
      CALL .Integer:
      JC .IB9:
.IB8: MOV [EBX+PGMOPT.ImageBaseLow],EAX
      MOV [EBX+PGMOPT.ImageBaseHigh],EDX
.IB9: RET

.FILEALIGN:
      JECXZ .FA8: ; If FILEALIGN= left empty, it will set later according to FORMAT= option.
      Invoke DictLookup::, DictAlignValue::, ESI,ECX ; Returned EAX=alignment value.
      JNC .FA8:
      CALL .Integer: ; Otherwise evaluate ESI,ECX as numeric expression.
      JC .FA9:
      CALL .PowerOf2
      JC .FA9:
.FA8: MOV [EBX+PGMOPT.FileAlign],EAX
.FA9: RET

.SECTIONALIGN:
      JECXZ .SA8: ; If SECTIONALIGN= left empty, it will set later according to FORMAT= option.
      Invoke DictLookup::, DictAlignValue::, ESI,ECX
      JNC .SA8:
      CALL .Integer:
      JC .SA9:
      CALL .PowerOf2:
      JC .SA9:
.SA8: MOV [EBX+PGMOPT.SectionAlign],EAX
.SA9: RET

.OUTFILE:
      JECXZ .OF8:
      PoolStore [Ea:: + EA.Pool],ESI,ECX,ZeroTerminate=Yes
      MOV [EBX+PGMOPT.OutFilePtr],EAX
.OF8: MOV [EBX+PGMOPT.OutFileSize],ECX
      RET

.STUBFILE:
      PoolStore [Ea:: + EA.Pool],ESI,ECX,ZeroTerminate=Yes
      MOV [EBX+PGMOPT.StubFilePtr],EAX
      MOV [EBX+PGMOPT.StubFileSize],ECX
      RET

.ICONFILE:
      JECXZ .IF8:
      PoolStore [Ea:: + EA.Pool],ESI,ECX,ZeroTerminate=Yes
      MOV [EBX+PGMOPT.IconFilePtr],EAX
 .IF8:MOV [EBX+PGMOPT.IconFileSize],ECX
      RET

; Options with constant factory default values, unchanged if specified as empty.

.SUBSYSTEM:
      JECXZ .SS9:
      Invoke DictLookup::, DictProgramSubsystems::, ESI,ECX
      JNC .SS8:
      CALL .Integer ; If not specified as enumerated value, try numeric value.
      JC .SS9:
      CALL .BoundW
      JC .SS9:
.SS8: MOV [EBX+PGMOPT.Subsystem],EAX
.SS9: RET

.LISTMAP:MOV EDI,pgmoptLISTMAP
      JMP .FlagStatus:
.LISTGLOBALS:MOV EDI,pgmoptLISTGLOBALS
      JMP .FlagStatus:
.LISTLITERALS:MOV EDI,pgmoptLISTLITERALS
      JMP .FlagStatus:

.ENTRY:
      JECXZ .EN8:
      PoolStore [Src:: + SRC.Pool],ESI,ECX
      JC .EN9:
      MOV [EBX+PGMOPT.EntryPtr],EAX
 .EN8:MOV [EBX+PGMOPT.EntrySize],ECX
 .EN9:RET

.DLLCHARACTERISTICS:
      JECXZ .DLL9:
      CALL .Integer:
      JC .DLL9:
      CALL .BoundW: ; Check if it fits to 16 bits.
      JC .DLL9:
      MOV [EBX+PGMOPT.DllCharacteristics],EAX
.DLL9:RET

.MAXPASSES:
      JECXZ .MP9:
      CALL .Integer:
      JC .MP9:
      CALL .BoundW:
      JC .MP9:
      MOV [EBX+PGMOPT.MaxPasses],EAX
 .MP9:RET

.MAXEXPANSIONS:
      JECXZ .ME9:
      CALL .Integer:
      JC .ME9:
      CALL .BoundD:
      JC .ME9:
      MOV [EBX+PGMOPT.MaxExpansions],EAX
.ME9: RET

.MAJOROSVERSION:
      JECXZ .MjO9:
      CALL .Integer:
      JC .MjO9:
      CALL .BoundW:
      JC .MjO9:
      MOV [EBX+PGMOPT.MajorOsVersion],EAX
.MjO9:RET

.MINOROSVERSION:
      JECXZ .MnO9:
      CALL .Integer:
      JC .MnO9:
      CALL .BoundW:
      JC .MnO9:
      MOV [EBX+PGMOPT.MinorOsVersion],EAX
.MnO9:RET

.MAJORSUBSYSTEMVERSION:
      JECXZ .MjS9:
      CALL .Integer:
      JC .MjS9:
      CALL .BoundW:
      JC .MjS9:
      MOV [EBX+PGMOPT.MajorSubsystemVersion],EAX
.MjS9:RET

.MINORSUBSYSTEMVERSION:
      JECXZ .MnS9:
      CALL .Integer:
      JC .MnS9:
      CALL .BoundW:
      JC .MnS9:
      MOV [EBX+PGMOPT.MinorSubsystemVersion],EAX
.MnS9:RET

.MAJORLINKERVERSION:
      JECXZ .MjLk9:
      CALL .Integer:
      JC .MjLk9:
      CALL .BoundB:
      JC .MjLk9:
      MOV [EBX+PGMOPT.MajorLinkerVersion],EAX
.MjLk9:RET

.MINORLINKERVERSION:
      JECXZ .MnLk9:
      CALL .Integer:
      JC .MnLk9:
      CALL .BoundB:
      JC .MnLk9:
      MOV [EBX+PGMOPT.MinorLinkerVersion],EAX
.MnLk9:RET

.MAJORIMAGEVERSION:
      JECXZ .MjI9:
      CALL .Integer:
      JC .MjI9:
      CALL .BoundW:
      JC .MjI9:
      MOV [EBX+PGMOPT.MajorImageVersion],EAX
.MjI9:RET

.MINORIMAGEVERSION:
      JECXZ .MnI9:
      CALL .Integer:
      JC .MnI9:
      CALL .BoundW:
      JC .MnI9:
      MOV [EBX+PGMOPT.MinorImageVersion],EAX
.MnI9:RET

.WIN32VERSIONVALUE:
      JECXZ .WV9:
      CALL .Integer:
      JC .WV9:
      CALL .BoundD:
      JC .WV9:
      MOV [EBX+PGMOPT.Win32VersionValue],EAX
.WV9: RET

.SIZEOFHEAPCOMMIT:
      JECXZ .SHC9:
      CALL .Integer:
      JC .SHC9:
      MOV [EBX+PGMOPT.SizeOfHeapCommitLow],EAX
      MOV [EBX+PGMOPT.SizeOfHeapCommitHigh],EDX
.SHC9:RET

.SIZEOFHEAPRESERVE:
      JECXZ .SHR9:
      CALL .Integer:
      JC .SHR9:
      MOV [EBX+PGMOPT.SizeOfHeapReserveLow],EAX
      MOV [EBX+PGMOPT.SizeOfHeapReserveHigh],EDX
.SHR9:RET

.SIZEOFSTACKCOMMIT:
      JECXZ .SSC9:
      CALL .Integer:
      JC .SSC9:
      MOV [EBX+PGMOPT.SizeOfStackCommitLow],EAX
      MOV [EBX+PGMOPT.SizeOfStackCommitHigh],EDX
.SSC9:RET

.SIZEOFSTACKRESERVE:
      JECXZ .SSR9:
      CALL .Integer:
      JC .SSR9:
      MOV [EBX+PGMOPT.SizeOfStackReserveLow],EAX
      MOV [EBX+PGMOPT.SizeOfStackReserveHigh],EDX
.SSR9:RET

 ; PROGRAM options evaluation helper subprocedures.

.BoundD: PROC ; Check if EDX=0. Return CF if not.
      CMP EDX,0x0000_0001
      CMC
      Msg cc=C,'3708',[%PgmoptNamePtr],[%PgmoptValuePtr] ; Value of !1S=!2S does not fit into 32 bits. Ignored.
      RET
     ENDP .BoundD:

.BoundW: PROC ; Check if integer EAX will fit into WORD. Return CF if not.
      CMP EAX,0x0001_0000
      CMC
      Msg cc=C,'3707',[%PgmoptNamePtr],[%PgmoptValuePtr] ; Value of !1S=!2S does not fit into 16 bits. Ignored.
      RET
     ENDP .BoundW:

.BoundB: PROC ; Check if integer EAX will fit into BYTE. Return CF if not.
      CMP EAX,0x0000_0100
      CMC
      Msg cc=C,'3706',[%PgmoptNamePtr],[%PgmoptValuePtr] ; Value of !1S=!2S does not fit into  8 bits. Ignored.
      RET
     ENDP .BoundB:

.PowerOf2: PROC ; Check if the value EAX is zero or a power of two. Return CF if not. Destroys ECX,EDX.
      BSF ECX,EAX
      BSR EDX,EAX
      JZ .90:
      CMP ECX,EDX
      JE .90:
.80:  Msg '3738',EAX ; Value !1D should be a power of 2. Ignored.
      STC
.90:  RET
    ENDP .PowerOf2:

.Integer: PROC ; Option value in ESI,ECX is evaluated as a scalar integer to EDX:EAX and %PgmoptExp.
 ; Input: ESI,ECX=option value ptr and size.
 ; Output: CF=0, EDX:EAX=32bit signed value, ECX,EDX modified.
 ; Error:  CF=1, Msg reported, EAX,ECX,EDX,EDI modified.
      LEA EDI,[%PgmoptExp]
      Invoke ExpEval::,EDI,ESI,ECX,0
      JC .90:
      MOV ECX,[EDI+EXP.Status]
      CMP CL,'N'
      JE .70:
      Msg '3721',[%PgmoptNamePtr],[%PgmoptValuePtr] ;  Scalar value expected instead of !1$=!2S
      STC
      JMP .90:
 .70: JSt [EBX+PGMOPT.Status],pgmoptWidth64,.80:
      CMP CH,7 ; Number magnitude exceedes 32 bits?
      JB .80:
      Msg '3708',[%PgmoptNamePtr],[%PgmoptValuePtr] ; Value of !1S=!2S does not fit into 32 bits. Ignored.
      STC
      JMP .90:
 .80: MOV EAX,[EDI+EXP.Low]
      MOV EDX,[EDI+EXP.High]
      CLC
 .90: RET
     ENDP .Integer:

.Boolean: PROC ; Option value in ESI,ECX is evaluated as Boolean. Returns EAX=0 or -1.
 ; Input: ESI,ECX=option value ptr and size.
 ; Output: CF=0, EAX=value 0 or -1, ECX,EDX,EDI modified.
 ; Error:  CF=1, EAX,ECX,EDX,EDI modified.
     Invoke DictLookup::, DictBoolean::, ESI,ECX ; YES/NO/TRUE/FALSE/ON/OFF etc.
     JNC .90: ; If enumerated boolean token found, EAX is 0 or -1.
     CALL PgmoptAssemble.Integer:
     JC .90:
     TEST EAX
     JZ .90:
     MOV EAX,-1
.90: RET
    ENDP .Boolean:

.FlagStatus: PROC ; Input: EDI=PGMOPT.Status flag mask, e.g. pgmoptLISTGLOBALS. ESI,ECX=source boolean value.
      PUSH EDI
        CALL PgmoptAssemble.Boolean: ; Returns EAX=0 or -1.
      POP EDI
      JC .90:
      AND EAX,EDI
      NOT EDI
      AND [EBX+PGMOPT.Status],EDI ; Reset bit.
      OR  [EBX+PGMOPT.Status],EAX ; Set if the option in EDI was TRUE.
 .90: RET
     ENDP .FlagStatus:

.99:EndProcedure PgmoptAssemble

↑ PgmoptSetDefaults PgmoptPtr: PgmoptSetDefaults checks nonstatic program options and sets them to default values if they were not specified explicitly in euroasm.ini or as keywords in pseudoinstruction PROGRAM, i.e. if they were left empty or omitted, which is signalized with empty string or with numeric value -1.
Option FORMAT= defaults to BIN.
Other options MODEL=,WIDTH=,IMAGEBASE=,SECTIONALIGN=,FILEALIGNdefault to values which depend on program format, see manual.
Input: PgmoptPtr Pointer to PGMOPT object to modify.
Output: Pgmopt is modified.
Error: -
See also: PfList.
Invoked by: PseudoPROGRAM
Invokes: CtxPeek EaBufferRelease EaBufferReserve EaId2Fs

PgmoptSetDefaults Procedure PgmoptPtr
      MOV EDI,[%PgmoptPtr]
      Invoke CtxPeek::,ctxPROGRAM,0
      JC .99: ; Skip if no source is loaded yet (global "euroasm.ini" is processed).
      MOV EBX,EAX ; Program context.
      Invoke EaBufferReserve::,PgmoptSetDefaults
      Invoke EaId2Fs::,[EBX+CTX.NamePtr],[EBX+CTX.NameSize],EAX
      BufferRetrieve EAX
      MOV EBX,ESI ; EBX,EDX is now filesystem-friendly program name.
      MOV EDX,ECX ; It will be used as default for OUTFILE.
      Invoke EaBufferRelease::,EAX

.FORMAT:PROC
      MOV EAX,pgmoptFormatMask
      AND EAX,[EDI+PGMOPT.Status]
      JNZ .90: ; If FORMAT= was explicitly specified, do not change.
      RstSt [EDI+PGMOPT.Status],pgmoptFormatMask+pgmoptLinkPropMask
      OR EAX,pgmoptBIN+pgmoptImage ; Otherwise use BIN as the default format.
      OR [EDI+PGMOPT.Status],EAX
  .90:ENDP .FORMAT:

.OUTFILE:PROC ; AL is one of pgmoptFormatMask.
      SUB ECX,ECX
      CMP [EDI+PGMOPT.OutFileSize],ECX
      JNZ .90: ; If OUTFILE= was explicitly specified, use it as is.
      ; Otherwise the output file name will be "%^Program"
      ;        concatenated with default format extension.
      MOV CL,4 ; Most usual extension size.
      Dispatch AL,%PfPgmoptList
.pgmoptBIN: MOV ESI,".bin"
       JMP .50:
.pgmoptCOM: MOV ESI,".com"
       JMP .50:
.pgmoptCOFF:
.pgmoptOMF: MOV ESI,".obj"
       JMP .50:
.pgmoptLIBOMF:
.pgmoptLIBCOF: MOV ESI,".lib"
       JMP .50:
.pgmoptDLL: MOV ESI,".dll"
       JMP .50:
.pgmoptRSRC:MOV ESI,".res"
       JMP .50:
.pgmoptMZ:
.pgmoptPE: MOV ESI,".exe"
       ;JMP .50:
  .50: ; ESI now contains ECX (1..4) characters of file extension.
      PUSH ECX
       LEA ECX,[EDX+ECX+1] ; %^Program + extension + zeroterminator.
       PoolNew [Src.Pool::],ECX,Align=BYTE
       DEC ECX
       MOV [EDI+PGMOPT.OutFilePtr],EAX
       MOV [EDI+PGMOPT.OutFileSize],ECX
       CopyTo EAX,EBX,Size=EDX ; Permanently save program name.
       ADD EAX,EDX
      POP ECX
      PUSH ESI
        MOV ESI,ESP
        CopyTo EAX,ESI,Size=ECX ; Append the extension.
        MOVB [EAX+ECX],0 ; Zero terminator.
      POP ESI
 .90:ENDP .OUTFILE:

.MODEL:PROC
      MOV EDX,[EDI+PGMOPT.Status]
      MOV EAX,pgmoptModelMask
      AND EAX,EDX
      JNZ .90: ; If MODEL= was explicitly specified, use it as is.
      ; Otherwise get default model for this program format.
      MOV EAX,pgmoptFormatMask
      AND EAX,EDX
      Dispatch AL,%PfPgmoptList
.pgmoptCOFF:
.pgmoptPE:
.pgmoptDLL:
.pgmoptLIBCOF:
.pgmoptRSRC:
.pgmoptCOFF64:
.pgmoptPE64:
       MOV EAX,pgmoptFLAT
       JMP .50:
.pgmoptBIN:
.pgmoptCOM:
       MOV EAX,pgmoptTINY
       JMP .50:
.pgmoptOMF:
.pgmoptLIBOMF:
.pgmoptMZ:
       MOV EAX,pgmoptSMALL
   .50:OR EDX,EAX
       OR [EDI+PGMOPT.Status],EDX
   .90:ENDP .MODEL:

.WIDTH:PROC
       MOV EAX,pgmoptWidthMask
       AND EAX,EDX
       JNZ .90: ; If WIDTH= was explicitly specified, use it as is.
       MOV EAX,pgmoptFormatMask
       AND EAX,EDX
       Dispatch AL,%PfPgmoptList
.pgmoptBIN:
.pgmoptCOM:
.pgmoptOMF:
.pgmoptMZ:
.pgmoptLIBOMF:
       JSt EDX,pgmoptHUGE|pgmoptFLAT,.pgmoptDLL: ; MODEL=HUGE|FLAT defaults to WIDTH=32.
       MOV EAX,pgmoptWidth16   ; Other realmode models default to WIDTH=16.
       JMP .50:
.pgmoptCOFF:
.pgmoptLIBCOF:
.pgmoptPE:
.pgmoptDLL:
.pgmoptRSRC:
       MOV EAX,pgmoptWidth32
   .50:OR EDX,EAX
       OR [EDI+PGMOPT.Status],EDX
   .90:ENDP .WIDTH:

.SECTIONALIGN:PROC
      XOR EAX,EAX
      DEC EAX
      CMP [EDI+PGMOPT.SectionAlign],EAX ; If not explicitly specified, SectionAlign=-1.
      JNE .90: ; Leave the explicitly specified alignment as is.
      MOV EAX,pgmoptFormatMask
      AND EAX,EDX
      Dispatch AL,%PfPgmoptList
.pgmoptBIN:
.pgmoptCOM:
.pgmoptMZ:
.pgmoptOMF:
.pgmoptLIBOMF:
.pgmoptLIBCOF:
.pgmoptCOFF:
      SUB EAX,EAX ; SectionAlign=0.
      JMP .50:
.pgmoptPE:
.pgmoptRSRC:
.pgmoptDLL:
       MOV EAX,4K ; SectionAlign=1000h.
   .50:MOV [EDI+PGMOPT.SectionAlign],EAX
   .90:ENDP .SECTIONALIGN:

.FILEALIGN:PROC
      XOR EAX,EAX
      DEC EAX
      CMP [EDI+PGMOPT.FileAlign],EAX ; If not explicitly specified, FileAlign=-1.
      JNE .90: ; Leave the explicitly specified alignment as is.
      MOV EAX,pgmoptFormatMask
      AND EAX,EDX
      Dispatch AL,%PfPgmoptList
.pgmoptBIN:
.pgmoptCOM:
.pgmoptMZ:
.pgmoptOMF:
.pgmoptLIBOMF:
.pgmoptLIBCOF:
.pgmoptRSRC:
.pgmoptCOFF:
       SUB EAX,EAX ; FileAlign=0.
       JMP .50:
.pgmoptPE:
.pgmoptDLL:
       MOV EAX,512
   .50:MOV [EDI+PGMOPT.FileAlign],EAX
   .90:ENDP .FILEALIGN:

.IMAGEBASE:PROC
      XOR EAX,EAX
      DEC EAX
      CMP [EDI+PGMOPT.ImageBaseLow], EAX ; If not explicitly specified, ImageBase=-1.
      JNE .90:
      CMP [EDI+PGMOPT.ImageBaseHigh],EAX ; If not explicitly specified, ImageBase=-1.
      JNE .90:                           ; Leave the explicitly specified base as is.
      MOV EAX,pgmoptFormatMask           ;  otherwise use the format-dependent default.
      AND EAX,EDX
      Dispatch AL,%PfPgmoptList
.pgmoptLIBCOF:
.pgmoptLIBOMF:
.pgmoptCOFF:
.pgmoptRSRC:
.pgmoptOMF:
.pgmoptBIN:
.pgmoptCOM:
.pgmoptMZ:
      SUB EAX,EAX  ; ImageBase=0.
      JMP .50:
.pgmoptPE:
      MOV EAX,4M   ; ImageBase=40_0000h.
      JMP .50:
.pgmoptDLL:
      MOV EAX,256M ; ImageBase=1000_0000h.
  .50:CDQ
      MOV [EDI+PGMOPT.ImageBaseLow],EAX
      MOV [EDI+PGMOPT.ImageBaseHigh],EDX
.90: ENDP .IMAGEBASE:
.99:EndProcedure PgmoptSetDefaults

    ENDPROGRAM pgmopt

▲Back to the top▲

pgmopt.htm Class PGMOPT Enumerations %PgmoptList Encoding PgmoptEnc Procedures PgmoptAssemble PgmoptSetDefaults PgmoptSetLinkProp

pgmopt.htm
Class
PGMOPT
Enumerations
%PgmoptList
Encoding
PgmoptEnc
Procedures
PgmoptAssemble
PgmoptSetDefaults
PgmoptSetLinkProp